Annex A (informative) Grammar Summary

Comment ::

MultiLineComment

SingleLineComment

MultiLineComment ::

/* MultiLineCommentChars_opt */

MultiLineCommentChars ::

MultiLineNotAsteriskChar MultiLineCommentChars_opt

* PostAsteriskCommentChars_opt

PostAsteriskCommentChars ::

MultiLineNotForwardSlashOrAsteriskChar MultiLineCommentChars_opt

* PostAsteriskCommentChars_opt

MultiLineNotAsteriskChar ::

SourceCharacter but not *

MultiLineNotForwardSlashOrAsteriskChar ::

SourceCharacter but not one of / or *

SingleLineComment ::

// SingleLineCommentChars_opt

SingleLineCommentChars ::

SingleLineCommentChar SingleLineCommentChars_opt

SingleLineCommentChar ::

SourceCharacter but not LineTerminator

See 7.5

Token ::

IdentifierName

Punctuator

NumericLiteral

StringLiteral

Identifier ::

IdentifierName but not ReservedWord

IdentifierName ::

IdentifierStart

IdentifierName IdentifierPart

IdentifierStart ::

UnicodeLetter

$

_

\ UnicodeEscapeSequence

IdentifierPart ::

IdentifierStart

UnicodeCombiningMark

UnicodeDigit

UnicodeConnectorPunctuation

<ZWNJ>

<ZWJ>

UnicodeLetter ::

any character in the Unicode categories “Uppercase letter (Lu)”, “Lowercase letter (Ll)”, “Titlecase letter (Lt)”, “Modifier letter (Lm)”, “Other letter (Lo)”, or “Letter number (Nl)”.

UnicodeCombiningMark ::

any character in the Unicode categories “Non-spacing mark (Mn)” or “Combining spacing mark (Mc)”

UnicodeDigit ::

any character in the Unicode category “Decimal number (Nd)”

UnicodeConnectorPunctuation ::

any character in the Unicode category “Connector punctuation (Pc)”

See 7.6.1

ReservedWord ::

Keyword

FutureReservedWord

NullLiteral

BooleanLiteral

See 7.6.1.1

Keyword :: one of

break	do	instanceof	typeof
case	else	new	var
catch	finally	return	void
continue	for	switch	while
debugger	function	this	with
default	if	throw
delete	in	try

See 7.6.1.2

FutureReservedWord :: one of

class	enum	extends	super
const	export	import

The following tokens are also considered to be FutureReservedWords when parsing strict mode code (see 10.1.1).

implements	let	private	public
interface	package	protected	static
yield

See 7.7

Punctuator :: one of

{	}	(	)	[	]
.	;	,	<	>	<=
>=	==	!=	===	!==
+	-	*	%	++	--
<<	>>	>>>	&	\|	^
!	~	&&	\|\|	?	:
=	+=	-=	*=	%=	<<=
>>=	>>>=	&=	\|=	^=

See 7.7

DivPunctuator :: one of

See 7.8

Literal ::

NullLiteral

BooleanLiteral

NumericLiteral

StringLiteral

RegularExpressionLiteral

See 7.8.1

NullLiteral ::

null

See 7.8.2

BooleanLiteral ::

true

false

NumericLiteral ::

DecimalLiteral

HexIntegerLiteral

DecimalLiteral ::

DecimalIntegerLiteral . DecimalDigits_opt ExponentPart_opt

. DecimalDigits ExponentPart_opt

DecimalIntegerLiteral ExponentPart_opt

DecimalIntegerLiteral ::

0

NonZeroDigit DecimalDigits_opt

DecimalDigits ::

DecimalDigit

DecimalDigits DecimalDigit

DecimalDigit :: one of

0 1 2 3 4 5 6 7 8 9

NonZeroDigit :: one of

1 2 3 4 5 6 7 8 9

ExponentPart ::

ExponentIndicator SignedInteger

ExponentIndicator :: one of

e E

SignedInteger ::

DecimalDigits

+ DecimalDigits

- DecimalDigits

HexIntegerLiteral ::

0x HexDigit

0X HexDigit

HexIntegerLiteral HexDigit

HexDigit :: one of

0 1 2 3 4 5 6 7 8 9 a b c d e f A B C D E F

StringLiteral ::

" DoubleStringCharacters_opt "

' SingleStringCharacters_opt '

DoubleStringCharacters ::

DoubleStringCharacter DoubleStringCharacters_opt

SingleStringCharacters ::

SingleStringCharacter SingleStringCharacters_opt

DoubleStringCharacter ::

SourceCharacter but not one of " or \ or LineTerminator

\ EscapeSequence

LineContinuation

SingleStringCharacter ::

SourceCharacter but not one of ' or \ or LineTerminator

\ EscapeSequence

LineContinuation

LineContinuation ::

\ LineTerminatorSequence

EscapeSequence ::

CharacterEscapeSequence

0 [lookahead ∉ DecimalDigit]

HexEscapeSequence

UnicodeEscapeSequence

CharacterEscapeSequence ::

SingleEscapeCharacter

NonEscapeCharacter

SingleEscapeCharacter :: one of

' " \ b f n r t v

NonEscapeCharacter ::

SourceCharacter but not one of EscapeCharacter or LineTerminator

EscapeCharacter ::

SingleEscapeCharacter

DecimalDigit

x

u

HexEscapeSequence ::

x HexDigit HexDigit

UnicodeEscapeSequence ::

u HexDigit HexDigit HexDigit HexDigit

RegularExpressionLiteral ::

/ RegularExpressionBody / RegularExpressionFlags

RegularExpressionBody ::

RegularExpressionFirstChar RegularExpressionChars

RegularExpressionChars ::

[empty]

RegularExpressionChars RegularExpressionChar

RegularExpressionFirstChar ::

RegularExpressionNonTerminator but not one of * or \ or / or [

RegularExpressionBackslashSequence

RegularExpressionClass

RegularExpressionChar ::

RegularExpressionNonTerminator but not \ or / or [

RegularExpressionBackslashSequence

RegularExpressionClass

RegularExpressionBackslashSequence ::

\ RegularExpressionNonTerminator

RegularExpressionNonTerminator ::

SourceCharacter but not LineTerminator

RegularExpressionClass ::

[ RegularExpressionClassChars ]

RegularExpressionClassChars ::

[empty]

RegularExpressionClassChars RegularExpressionClassChar

RegularExpressionClassChar ::

RegularExpressionNonTerminator but not ] or \

RegularExpressionBackslashSequence

RegularExpressionFlags ::

[empty]

RegularExpressionFlags IdentifierPart

A.2 Number Conversions

StringNumericLiteral :::

StrWhiteSpace_opt

StrWhiteSpace_opt StrNumericLiteral StrWhiteSpace_opt

StrWhiteSpace :::

StrWhiteSpaceChar StrWhiteSpace_opt

StrWhiteSpaceChar :::

WhiteSpace

LineTerminator

StrNumericLiteral :::

StrDecimalLiteral

HexIntegerLiteral

StrDecimalLiteral :::

StrUnsignedDecimalLiteral

+ StrUnsignedDecimalLiteral

- StrUnsignedDecimalLiteral

StrUnsignedDecimalLiteral :::

Infinity

DecimalDigits . DecimalDigits_opt ExponentPart_opt

. DecimalDigits ExponentPart_opt

DecimalDigits ExponentPart_opt

DecimalDigits :::

DecimalDigit

DecimalDigits DecimalDigit

DecimalDigit ::: one of

0 1 2 3 4 5 6 7 8 9

ExponentPart :::

ExponentIndicator SignedInteger

ExponentIndicator ::: one of

e E

SignedInteger :::

DecimalDigits

+ DecimalDigits

- DecimalDigits

HexIntegerLiteral :::

0x HexDigit

0X HexDigit

HexIntegerLiteral HexDigit

HexDigit ::: one of

0 1 2 3 4 5 6 7 8 9 a b c d e f A B C D E F

A.3 Expressions

See 11.1

PrimaryExpression :

this

Identifier

Literal

ArrayLiteral

ObjectLiteral

( Expression )

See 11.1.4

ArrayLiteral :

[ Elision_opt ]

[ ElementList ]

[ ElementList , Elision_opt ]

See 11.1.4

ElementList :

Elision_opt AssignmentExpression

ElementList , Elision_opt AssignmentExpression

See 11.1.4

Elision :

,

Elision ,

ObjectLiteral :

{ }

{ PropertyNameAndValueList }

{ PropertyNameAndValueList , }

PropertyNameAndValueList :

PropertyAssignment

PropertyNameAndValueList , PropertyAssignment

PropertyAssignment :

PropertyName : AssignmentExpression

get PropertyName ( ) { FunctionBody }

set PropertyName ( PropertySetParameterList ) { FunctionBody }

PropertyName :

IdentifierName

StringLiteral

NumericLiteral

PropertySetParameterList :

Identifier

MemberExpression :

PrimaryExpression

FunctionExpression

MemberExpression [ Expression ]

MemberExpression . IdentifierName

new MemberExpression Arguments

NewExpression :

MemberExpression

new NewExpression

CallExpression :

MemberExpression Arguments

CallExpression Arguments

CallExpression [ Expression ]

CallExpression . IdentifierName

Arguments :

( )

( ArgumentList )

ArgumentList :

AssignmentExpression

ArgumentList , AssignmentExpression

LeftHandSideExpression :

NewExpression

CallExpression

See 11.3

PostfixExpression :

LeftHandSideExpression

LeftHandSideExpression [no LineTerminator here] ++

LeftHandSideExpression [no LineTerminator here] --

See 11.4

UnaryExpression :

PostfixExpression

delete UnaryExpression

void UnaryExpression

typeof UnaryExpression

++ UnaryExpression

-- UnaryExpression

+ UnaryExpression

- UnaryExpression

~ UnaryExpression

! UnaryExpression

See 11.5

MultiplicativeExpression :

UnaryExpression

MultiplicativeExpression * UnaryExpression

MultiplicativeExpression / UnaryExpression

MultiplicativeExpression % UnaryExpression

See 11.6

AdditiveExpression :

MultiplicativeExpression

AdditiveExpression + MultiplicativeExpression

AdditiveExpression - MultiplicativeExpression

See 11.7

ShiftExpression :

AdditiveExpression

ShiftExpression << AdditiveExpression

ShiftExpression >> AdditiveExpression

ShiftExpression >>> AdditiveExpression

See 11.8

RelationalExpression :

ShiftExpression

RelationalExpression < ShiftExpression

RelationalExpression > ShiftExpression

RelationalExpression <= ShiftExpression

RelationalExpression >= ShiftExpression

RelationalExpression instanceof ShiftExpression

RelationalExpression in ShiftExpression

See 11.8

RelationalExpressionNoIn :

ShiftExpression

RelationalExpressionNoIn < ShiftExpression

RelationalExpressionNoIn > ShiftExpression

RelationalExpressionNoIn <= ShiftExpression

RelationalExpressionNoIn >= ShiftExpression

RelationalExpressionNoIn instanceof ShiftExpression

See 11.9

EqualityExpression :

RelationalExpression

EqualityExpression == RelationalExpression

EqualityExpression != RelationalExpression

EqualityExpression === RelationalExpression

EqualityExpression !== RelationalExpression

See 11.9

EqualityExpressionNoIn :

RelationalExpressionNoIn

EqualityExpressionNoIn == RelationalExpressionNoIn

EqualityExpressionNoIn != RelationalExpressionNoIn

EqualityExpressionNoIn === RelationalExpressionNoIn

EqualityExpressionNoIn !== RelationalExpressionNoIn

BitwiseANDExpression :

EqualityExpression

BitwiseANDExpression & EqualityExpression

BitwiseANDExpressionNoIn :

EqualityExpressionNoIn

BitwiseANDExpressionNoIn & EqualityExpressionNoIn

BitwiseXORExpression :

BitwiseANDExpression

BitwiseXORExpression ^ BitwiseANDExpression

BitwiseXORExpressionNoIn :

BitwiseANDExpressionNoIn

BitwiseXORExpressionNoIn ^ BitwiseANDExpressionNoIn

BitwiseORExpression :

BitwiseXORExpression

BitwiseORExpression | BitwiseXORExpression

BitwiseORExpressionNoIn :

BitwiseXORExpressionNoIn

BitwiseORExpressionNoIn | BitwiseXORExpressionNoIn

LogicalANDExpression :

BitwiseORExpression

LogicalANDExpression && BitwiseORExpression

LogicalANDExpressionNoIn :

BitwiseORExpressionNoIn

LogicalANDExpressionNoIn && BitwiseORExpressionNoIn

LogicalORExpression :

LogicalANDExpression

LogicalORExpression || LogicalANDExpression

LogicalORExpressionNoIn :

LogicalANDExpressionNoIn

LogicalORExpressionNoIn || LogicalANDExpressionNoIn

See 11.12

ConditionalExpression :

LogicalORExpression

LogicalORExpression ? AssignmentExpression : AssignmentExpression

See 11.12

ConditionalExpressionNoIn :

LogicalORExpressionNoIn

LogicalORExpressionNoIn ? AssignmentExpression : AssignmentExpressionNoIn

See 11.13

AssignmentExpression :

ConditionalExpression

LeftHandSideExpression = AssignmentExpression

LeftHandSideExpression AssignmentOperator AssignmentExpression

See 11.13

AssignmentExpressionNoIn :

ConditionalExpressionNoIn

LeftHandSideExpression = AssignmentExpressionNoIn

LeftHandSideExpression AssignmentOperator AssignmentExpressionNoIn

See 11.13

AssignmentOperator : one of

<<=

>>=

>>>=

See 11.14

Expression :

AssignmentExpression

Expression , AssignmentExpression

See 11.14

ExpressionNoIn :

AssignmentExpressionNoIn

ExpressionNoIn , AssignmentExpressionNoIn

A.4 Statements

See clause 12

Statement :

Block

VariableStatement

EmptyStatement

ExpressionStatement

IfStatement

IterationStatement

ContinueStatement

BreakStatement

ReturnStatement

WithStatement

LabelledStatement

SwitchStatement

ThrowStatement

TryStatement

DebuggerStatement

See 12.1

Block :

{ StatementList_opt }

See 12.1

StatementList :

Statement

StatementList Statement

VariableStatement :

var VariableDeclarationList ;

VariableDeclarationList :

VariableDeclaration

VariableDeclarationList , VariableDeclaration

VariableDeclarationListNoIn :

VariableDeclarationNoIn

VariableDeclarationListNoIn , VariableDeclarationNoIn

VariableDeclaration :

Identifier Initialiser_opt

VariableDeclarationNoIn :

Identifier InitialiserNoIn_opt

Initialiser :

= AssignmentExpression

InitialiserNoIn :

= AssignmentExpressionNoIn

See 12.3

EmptyStatement :

;

See 12.4

ExpressionStatement :

[lookahead ∉ {{, function}] Expression ;

See 12.5

IfStatement :

if ( Expression ) Statement else Statement

if ( Expression ) Statement

See 12.6

IterationStatement :

do Statement while ( Expression );

while ( Expression ) Statement

for ( ExpressionNoIn_opt ; Expression_opt ; Expression_opt ) Statement

for ( var VariableDeclarationListNoIn ; Expression_opt ; Expression_opt ) Statement

for ( LeftHandSideExpression in Expression ) Statement

for ( var VariableDeclarationNoIn in Expression ) Statement

See 12.7

ContinueStatement :

continue ;

continue [no LineTerminator here] Identifier ;

See 12.8

BreakStatement :

break ;

break [no LineTerminator here] Identifier ;

See 12.9

ReturnStatement :

return ;

return [no LineTerminator here] Expression ;

See 12.10

WithStatement :

with ( Expression ) Statement

SwitchStatement :

switch ( Expression ) CaseBlock

CaseBlock :

{ CaseClauses_opt }

{ CaseClauses_opt DefaultClause CaseClauses_opt }

CaseClauses :

CaseClause

CaseClauses CaseClause

CaseClause :

case Expression : StatementList_opt

DefaultClause :

default : StatementList_opt

See 12.12

LabelledStatement :

Identifier : Statement

See 12.13

ThrowStatement :

throw [no LineTerminator here] Expression ;

See 12.14

TryStatement :

try Block Catch

try Block Finally

try Block Catch Finally

See 12.14

Catch :

catch ( Identifier ) Block

See 12.14

Finally :

finally Block

See 12.15

DebuggerStatement :

debugger ;

A.5 Functions and Programs

FunctionDeclaration :

function Identifier ( FormalParameterList_opt ) { FunctionBody }

FunctionExpression :

function Identifier_opt ( FormalParameterList_opt ) { FunctionBody }

FormalParameterList :

Identifier

FormalParameterList , Identifier

FunctionBody :

SourceElements_opt

See clause 14

Program :

SourceElements_opt

See clause 14

SourceElements :

SourceElement

SourceElements SourceElement

See clause 14

SourceElement :

Statement

FunctionDeclaration

A.6 Universal Resource Identifier Character Classes

uri :::

uriCharacters_opt

uriCharacters :::

uriCharacter uriCharacters_opt

uriCharacter :::

uriReserved

uriUnescaped

uriEscaped

uriReserved ::: one of

; / ? : @ & = + $ ,

uriUnescaped :::

uriAlpha

DecimalDigit

uriMark

uriEscaped :::

% HexDigit HexDigit

uriAlpha ::: one of

a b c d e f g h i j k l m n o p q r s t u v w x y z

A B C D E F G H I J K L M N O P Q R S T U V W X Y Z

uriMark ::: one of

- _ . ! ~ * ' ( )

A.7 Regular Expressions

Pattern ::

Disjunction

Disjunction ::

Alternative

Alternative | Disjunction

Alternative ::

[empty]

Alternative Term

Term ::

Assertion

Atom

Atom Quantifier

Assertion ::

^

$

\ b

\ B

( ? = Disjunction )

( ? ! Disjunction )

Quantifier ::

QuantifierPrefix

QuantifierPrefix ?

QuantifierPrefix ::

*

+

?

{ DecimalDigits }

{ DecimalDigits , }

{ DecimalDigits , DecimalDigits }

Atom ::

PatternCharacter

.

\ AtomEscape

CharacterClass

( Disjunction )

( ? : Disjunction )

PatternCharacter ::

SourceCharacter but not one of -

^ $ \ . * + ? ( ) [ ] { } |

AtomEscape ::

DecimalEscape

CharacterEscape

CharacterClassEscape

CharacterEscape ::

ControlEscape

c ControlLetter

HexEscapeSequence

UnicodeEscapeSequence

IdentityEscape

ControlEscape :: one of

f n r t v

ControlLetter :: one of

a b c d e f g h i j k l m n o p q r s t u v w x y z

A B C D E F G H I J K L M N O P Q R S T U V W X Y Z

IdentityEscape ::

SourceCharacter but not IdentifierPart

<ZWJ>

<ZWNJ>

DecimalEscape ::

DecimalIntegerLiteral [lookahead ∉ DecimalDigit]

CharacterClassEscape :: one of

d D s S w W

CharacterClass ::

[ [lookahead ∉ {^}] ClassRanges ]

[ ^ ClassRanges ]

ClassRanges ::

[empty]

NonemptyClassRanges

NonemptyClassRanges ::

ClassAtom

ClassAtom NonemptyClassRangesNoDash

ClassAtom – ClassAtom ClassRanges

NonemptyClassRangesNoDash ::

ClassAtom

ClassAtomNoDash NonemptyClassRangesNoDash

ClassAtomNoDash – ClassAtom ClassRanges

ClassAtom ::

-

ClassAtomNoDash

ClassAtomNoDash ::

SourceCharacter but not one of \ or ] or -

\ ClassEscape

ClassEscape ::

DecimalEscape

b

CharacterEscape

CharacterClassEscape

A.8 JSON

A.8.1 JSON Lexical Grammar

JSONWhiteSpace ::

<TAB>

<CR>

<LF>

<SP>

JSONString ::

" JSONStringCharacters_opt "

JSONStringCharacters ::

JSONStringCharacter JSONStringCharacters_opt

JSONStringCharacter ::

SourceCharacter but not one of " or \ or U+0000 through U+001F

\ JSONEscapeSequence

JSONEscapeSequence ::

JSONEscapeCharacter

UnicodeEscapeSequence

JSONEscapeCharacter :: one of

" / \ b f n r t

JSONNumber ::

-_opt DecimalIntegerLiteral JSONFraction_opt ExponentPart_opt

JSONFraction ::

. DecimalDigits

JSONNullLiteral ::

NullLiteral

JSONBooleanLiteral ::

BooleanLiteral

A.8.2 JSON Syntactic Grammar

JSONText :

JSONValue

JSONValue :

JSONNullLiteral

JSONBooleanLiteral

JSONObject

JSONArray

JSONString

JSONNumber

JSONObject :

{ }

{ JSONMemberList }

JSONMember :

JSONString : JSONValue

JSONMemberList :

JSONMember

JSONMemberList , JSONMember

JSONArray :

[ ]

[ JSONElementList ]